home *** CD-ROM | disk | FTP | other *** search
/ Run Magazine ReRun 1987 March & April / rerun-1987-03-04.d64 / menu 64 (.txt) < prev    next >
Commodore BASIC  |  2022-09-20  |  2KB  |  63 lines
  1. 1 rem *********************************
  2. 2 rem *         'auto menu'           *
  3. 3 rem * reads directory & auto loads  *
  4. 4 rem * program selected by the user  *
  5. 5 rem *             by                *
  6. 6 rem * joe w. rocke          7/27/84 *
  7. 7 rem *********************************
  8. 10 poke53280,0:poke53281,0
  9. 20 dim n$(100):cx=54272:print "[147]"
  10. 30 print"[147][129]"
  11. 40 x$="                                       "
  12. 50 forx=1to5:printx$:next
  13. 60 print"":print chr$(117);
  14. 70 for x=1 to 38:printchr$(100);:next
  15. 80 printchr$(105);:for x=1 to 5
  16. 90 printchr$(103)spc(38)chr$(104)" "chr$(157);:next
  17. 100 printchr$(106);:for x=1 to 38:printchr$(102);:next:printchr$(107)
  18. 110 print""tab(14)"* auto menu *"
  19. 120 printtab(12)"[158]reading directory"
  20. 129 rem --- read disk directory ---
  21. 130 open1,8,0,"$"
  22. 140 get#1,b$:ifst<>0then260
  23. 149 rem --- line 150 limits to 26 files ---
  24. 150 iff>=27then260
  25. 160 ifb$<>chr$(34)then140
  26. 170 n$="":print"":poke 214,8:print
  27. 180 get#1,b$:ifb$<>chr$(34)thenn$=n$+b$:goto180
  28. 190 get#1,b$:ifb$=chr$(32)then190
  29. 199 rem -- following lines skip the loading files --
  30. 200 ifn$="boot"thenf=f-1:goto240
  31. 220 ifleft$(n$,1)=" "thenf=f-1:goto240
  32. 230 n$(f)=" "+n$
  33. 240 get#1,b$:ifb$<>""then240
  34. 250 ifst=0thenf=f+1:goto140
  35. 260 close1
  36. 269 rem - print first column of names -
  37. 270 fore=1tof/2:print"[153]"chr$(64+e)""n$(e):next
  38. 280 print"":poke214,8:print
  39. 289 rem -- then 2nd column of names ---
  40. 290 fore=f/2+1tof:printspc(20)"[153]"chr$(64+e)""n$(e):next
  41. 300 print""
  42. 310 printtab(12)"[158] press letter key "
  43. 320 printtab(5)"to auto load program selected"
  44. 330 getm$:ifm$=""then 330
  45. 340 ifm$=chr$(13)thenrun
  46. 350 ifm$<"a"orm$>chr$(64+f)then330
  47. 360 p=asc(m$)-64:print"[147]"
  48. 370 iflen(n$(p))>12thenn$(p)=left$(n$(p),12)+"*"
  49. 380 n$(p)=mid$(n$(p),2,len(n$(p)))
  50. 390 print"load"chr$(34)n$(p)chr$(34)",8[145][145][145]"
  51. 400 rem *******************************
  52. 410 rem * if you know the pgm is 'ml' *
  53. 420 rem * the example below will load *
  54. 430 rem * and file & run it. examples *
  55. 440 rem * (3) are shown below.        *
  56. 450 rem *******************************
  57. 460 ifleft$(n$(p),4)="tool"thena$="sys64738"+chr$(13):goto500
  58. 470 ifleft$(n$(p),12)="constructio*"thena$="sys49152"+chr$(13):goto500
  59. 480 ifleft$(n$(p),5)="ultra"thena$="sys49152"+chr$(13):goto500
  60. 490 a$="run"+chr$(13)
  61. 500 poke631,13:forb=1tolen(a$):poke631+b,asc(mid$(a$,b,1)):next:poke198,10
  62. 510 new
  63.